# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit qt4 toolchain-funcs

DESCRIPTION="A GUI front-end to gnuplot"
HOMEPAGE="http://sourceforge.jp/projects/cueplot/"
SRC_URI="mirror://sourceforge.jp/cueplot/28712/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="linguas_ja"

DEPEND="$(qt4_min_version 4.2)"
RDEPEND=">=sci-visualization/gnuplot-4.0"

src_unpack() {
	unpack "${A}"
	cd "${S}"
}

src_compile() {
	cd src
	qmake ${PN}.pro \
		QTDIR=/usr/$(get_libdir) \
		QMAKE=/usr/bin/qmake \
		QMAKE_CC=$(tc-getCC) \
		QMAKE_CXX=$(tc-getCXX) \
		QMAKE_LINK=$(tc-getCXX) \
		QMAKE_TARGET=release \
		QMAKE_CFLAGS_RELEASE="${CFLAGS}" \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE_LFLAGS_RELEASE="${LDFLAGS}" \
		|| die "qmake failed"
	
	emake || die "make failed"
}

src_install() {
	cd src
	exeinto /usr/$(get_libdir)/${PN}/
	doexe "${PN}"

	if use linguas_ja; then
		lrelease ${PN}.pro
		insinto /usr/$(get_libdir)/${PN}/
		doins ${PN}_ja_JP.qm
		if ! has_version '>=x11-libs/qt-4.3.0'; then
			doins qt_ja_JP.qm
		fi
	fi

	dosym /usr/$(get_libdir)/${PN}/${PN} /usr/bin/

	insinto /usr/share/applications/
	doins ${PN}.desktop
}